***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Mar 24, 2020                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJS6604_Pch-part   D   G   S
*****param & model definition***
.model  dmos  pmos(
+    l = 1e-6		  w = 1e-6			level = 3
+  vto = -0.982		 kp = 10.03		   rb = 2.545e-2)
.model  dds   d(
+   is = 8.644e-13	  n = 1.122e0		   rs = 3.216e-2		ikf = 4.842e-2
+   eg = 1.152e0       trs1 = -1.292e-3 )
.model  dbody d(
+   is = 9.644e-13	  n = 1.122e0		   rs = 3.216e-2		ikf = 4.842e-2
+   eg = 1.152e0       trs1 = -1.292e-3
+  cjo = 6.718e-11	  m = 3.542e-1		   vj = 1.428e-1
+   bv = 33		ibv = 250e-6		 tbv1 = 8.003e-4		 tt = 25n)
.model  inter  pmos(
+  vto = 0		 kp = 10		level = 1)
.model  dgd   d(
+  cjo = 2.378e-10	  m = 6.375e-1		   vj = 3.484e-1)
.param
+  cgs = 2.307e-10	cgd = 4.140e-10
+   rd = 3.267e-2	 ra = 3.233e-2		 trd1 = 7.349e-3
*****function & circuit***
rg	 G   1t   1
cgs	 1t   3   {cgs}
egv	 3   2t   table   {v(S, 1t)}
+((0.00 , 0.00 ),
+ (1.00 , 1.00 ),
+ (2.00 , 2.00 ),
+ (2.25 , 2.25 ),
+ (2.50 , 2.50 ),
+ (2.75 , 2.75 ),
+ (3.00 , 3.00 ),
+ (4.00 , 4.00 ),
+ (4.50 , 4.50 ),
+ (6.00 , 6.00 ),
+ (8.00 , 6.50 ),
+ (10.0 , 6.80 ),
+ (12.0 , 7.00 ),
+ (14.0 , 7.00 ))
egt	  1  2t   value = {4.021e-4*limit(v(2t,3),-5,0)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd1}
dds	  4   3   dds
dbody	  D   3   dbody
ra	  4   2   {ra}
rs	  3   5   1e-4
ls	  5   S   0.001n
m1       1t   8   6   6   inter
e1        8   6   4  1t   2
cgd	  7   4   {cgd}
rcgd      7   4   10meg
dgd       4   6   dgd
rdgd      4   6   10meg
m2        7   9  1t  1t   inter
e2        9  1t   4  1t   -2
.ends
*$
.subckt   PJS6604_Nch-part   D   G   S
*****param & model definition***
.model  dmos  nmos(
+    l = 1e-6		  w = 1e-6		level = 3
+  vto = .78		 kp = 18.37		   rb = 3e-2)
.model  dds   d(
+   is = 2.087e-11	  n = 1.208		   rs = 2.552e-2		 ikf = 7.338e-1
+   eg = 1.052	       trs1 = -5.378e-3 )
.model  dbody d(
+   is = 9.087e-12	  n = 1.208		   rs = 2.552e-2		 ikf = 7.338e-1
+   eg = 1.052	       trs1 = -5.378e-3 )
+  cjo = 3.998e-11	  m = 2.664e-1		   vj = 1.299e-1
+   bv = 33		ibv = 250e-6		 tbv1 = 2.521e-3		tbv2 = -7.508e-6
+   tt = 25n)
.model  inter  nmos(
+  vto = 0		 kp = 10		level = 1)
.model  dgd   d(
+  cjo = 2.358e-10	  m = 6.274e-1		   vj = 2.419e-1)
.param
+  cgs = 4.419e-10	cgd = 2.269e-10
+   rd = 1.210e-2	 ra = 5.827e-3		 trd1 = 1.225e-2
*****function & circuit***
rg	  G  1t   1
cgs	 1t   3   {cgs}
egv	 2t   3   table   {v(1t, S)}
+((0.00 , 0.00 ),
+ (0.50 , 0.50 ),
+ (1.00 , 1.00 ),
+ (1.50 , 1.50 ),
+ (2.00 , 2.00 ),
+ (2.50 , 2.50 ),
+ (3.00 , 2.80 ),
+ (4.00 , 3.10 ),
+ (5.00 , 3.22 ),
+ (7.00 , 3.40 ),
+ (8.00 , 3.48 ),
+ (10.0 , 3.52 ),
+ (12.0 , 3.58 ),
+ (14.0 , 3.58 ))
egt	  1  2t   value = {5.987e-4*limit(v(2t,3),0,5)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd1}
dds	  3   4   dds
dbody	  3   D   dbody
ra	  4   2   {ra}
rs	  3   5   1e-4
ls	  5   S   0.001n
m1       1t   8   6   6   inter
e1        8   6   4  1t   2
cgd	  7   4   {cgd}
rcgd      7   4   10meg
dgd       6   4   dgd
rdgd      4   6   10meg
m2        7   9  1t  1t   inter
e2        9  1t   4  1t   -2
.ends
*$
